ユーザーが選択した場合にのみ、InnoSetupでファイルをダウンロードする

質問：zipである2番目のファイルをダウンロードするスクリプトを作成する方法を知りたいのですが、最初は2つのzipファイルから選択できます。zipをダウンロード、解凍、削除します。zipファイルにはそれぞれ異なる名前がありますが、内容にはzipとは異なる名前があります（それぞれ同じ名前）。名前を変更する必要はありません。この質問は、inno-setupでのダウンロードファイルの条件の適用に少し似ています

問題のファイルは、SourceForgeのWebサイトからダウンロードされます。これらのファイルが対象としているプログラム（クローン）は、SFにリストされていないか、目的が変更されています。

PCharバグを修正した後：InnoToolsDownloaderがInno5.5で動作しない2011年からこのInnoSetupスクリプトを再利用できるようになりましたが、少し拡張したいのですが、苦労しています。

#include ReadReg(HKEY_LOCAL_MACHINE,'Software\Sherlock Software\InnoTools\Downloader','ScriptPath','');

[Code]
procedure InitializeWizard();
begin
  itd_init;

  { Set download source.. }
  itd_addfile('http://www.example.com/Textfile.txt', ExpandConstant('{tmp}\Textfile.txt'));
  itd_setoption('UI_AllowContinue','1');
  itd_setoption('UI_DetailedMode','1');
  { Start the download after the "Ready to install" screen is shown }
  itd_downloadafter(wpReady);
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssInstall then { Lets install the downloaded files }
  begin 
    FileCopy(ExpandConstant('{tmp}\Textfile.txt'), ExpandConstant('{userappdata}\program_name\Textfile.txt'), false);
  end;
end;

答えに基づく作業コード：

#pragma include __INCLUDE__ + ";" + "c:\lib\InnoDownloadPlugin"
[Setup]
...
CreateUninstallRegKey=no
#include <idp.iss>
...

[Types]
Name: full;    Description: "Full installation"
Name: compact; Description: "Compact installation"
Name: custom;  Description: "Custom installation"; Flags: iscustom

[Components]
Name: abc;  Description: "C File";  Types: full compact custom; Flags: fixed
Name: hlnj;  Description: "HL (Recommended)"; Types: custom; Flags: exclusive
Name: hnj; Description: "HF";  Types: custom; Flags: exclusive

[Files]
Source: "{tmp}\text.net";  DestDir: "{userappdata}\ccc"; Flags: external; Components: abc
Source: "{tmp}\HLNJ.zip";  DestDir: "{userappdata}\ccc"; Flags: external; Components: hlnj
Source: "{tmp}\HNJ.zip"; DestDir: "{userappdata}\ccc"; Flags: external; Components: hnj

[Code]
procedure InitializeWizard;
begin
  idpAddFileComp('http://www.example.com/text.net', ExpandConstant('{tmp}\text.net'), 'abc');
  idpAddFileComp('http://www.example.com/SecurityUpdates/HLNJ.zip', ExpandConstant('{tmp}\HLNJ.zip'), 'hlnj');
  idpAddFileComp('http://www.example.com/SecurityUpdates/HNJ.zip', ExpandConstant('{tmp}\HNJ.zip'), 'hnj');

  idpDownloadAfter(wpReady);
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssPostInstall then 
  begin
    FileCopy(ExpandConstant('{tmp}\text.net'), ExpandConstant('{userappdata}\ccc\text.net'), false);
    FileCopy(ExpandConstant('{tmp}\HLNJ.zip'), ExpandConstant('{userappdata}\ccc\HLNJ.txt'), false);
    FileCopy(ExpandConstant('{tmp}\HNJ.zip'), ExpandConstant('{userappdata}\ccc\HNJ.txt'), false);
  end;
end;

回答を投稿して初めて、質問にinno-download-pluginのタグを付けているにもかかわらず、実際にはInnoToolsDownloaderを使用していることに気付きました。してはいけないこと– InnoTools Downloaderは死んでいて、メンテナンスされていません。

また、今後のInno Setup 6.1には、ダウンロードのサポートが組み込まれていることに注意してください。このAPIを使用すると、ソリューションはより簡単になりますが、以下に示すIDPとは異なります。

examplesInnoダウンロードプラグインのインストールのフォルダがあるcomponents1.issとcomponents2.iss例。

1つ目はidpAddFileComp、コンポーネントが選択されたときに、条件付きでファイルをダウンロードするために使用する方法を示しています。

私は完全な例を再投稿しています：

; Uncomment one of following lines, if you haven't checked "Add IDP include path to ISPPBuiltins.iss" option during IDP installation:
;#pragma include __INCLUDE__ + ";" + ReadReg(HKLM, "Software\Mitrich Software\Inno Download Plugin", "InstallDir")
;#pragma include __INCLUDE__ + ";" + "c:\lib\InnoDownloadPlugin"

[Setup]
AppName          = My Program
AppVersion       = 1.0
DefaultDirName   = {pf}\My Program
DefaultGroupName = My Program
OutputDir        = userdocs:Inno Setup Examples Output

#include <idp.iss>

[Types]
Name: full;    Description: "Full installation"
Name: compact; Description: "Compact installation"
Name: custom;  Description: "Custom installation"; Flags: iscustom

[Components]
Name: app;  Description: "My Program";  Types: full compact custom; Flags: fixed
Name: help; Description: "Help files";  Types: full
Name: src;  Description: "Source code"; Types: full

[Files]
Source: "{tmp}\app.exe";  DestDir: "{app}"; Flags: external; ExternalSize: 1048576; Components: app
Source: "{tmp}\help.chm"; DestDir: "{app}"; Flags: external; ExternalSize: 1048576; Components: help
Source: "{tmp}\src.zip";  DestDir: "{app}"; Flags: external; ExternalSize: 1048576; Components: src

[Icons]
Name: "{group}\My Program"; Filename: "app.exe";  Components: app
Name: "{group}\Help file";  Filename: "help.chm"; Components: help
Name: "{group}\{cm:UninstallProgram,My Program}"; Filename: "{uninstallexe}"

[Code]
procedure InitializeWizard;
begin
    idpAddFileComp('http://127.0.0.1/app.exe',  ExpandConstant('{tmp}\app.exe'),  'app');
    idpAddFileComp('http://127.0.0.1/help.chm', ExpandConstant('{tmp}\help.chm'), 'help');
    idpAddFileComp('http://127.0.0.1/src.zip',  ExpandConstant('{tmp}\src.zip'),  'src');

    idpDownloadAfter(wpReady);
end;

警告：渡されるコンポーネント名idpAddFileComp は小文字である必要があります（実際のコンポーネント名は大文字を使用できます）。

Inno Setup 6.1.2にはDownloadTemporaryFile、サードパーティのツールを使用せずにファイルをダウンロードするための新しいサポート機能があります。

• HTTPS（ただし、期限切れまたは自己署名証明書はサポートしません）およびHTTPをサポートします。
• リダイレクトは自動的に実行され、プロキシ設定が自動的に使用されます。
• 既存のサードパーティツールとは異なり、サービスから安全に使用できます。
• ダウンロードしたファイルのSHA-256ハッシュチェックをサポートします。
• 基本認証をサポートします。

受け入れられた回答で参照されているIDPプラグインでさえ2016年に最後に更新され、現在は機能せず、Inno Setup6.1.2によって提供される新しい機能に変更する必要があったため、この回答を追加しました。