Inno Setup：ExtractTemporaryFileによりウィザードがフリーズする

ユーザーの選択に応じて、特定のredistツールのインストールを管理するためのカスタムページを作成しました。

これらのツールは、ユーザーがこれらのツールをインストールするかどうかを確認するチェックボックスにリンクされています。次に、そこにのみページが表示され、各ツールのインストールの進行状況がユーザーに表示されます。

ここでの問題は、ツールのセットアップの最初のExtractTemporaryFileが完了したときにのみ進行状況ページが表示され、最後のページがフリーズしたかのように表示されることです。

ExtractTemporaryFileが発生する前に進行状況ページを表示させる唯一の方法は、インストール関数の前にMsgBoxを配置することです。ただし、この場合でも、ExtractTemporaryFileを起動すると、ExtractTemporaryFileが完了するまでプログレスバーアニメーションがフリーズします...

これを行うコードの一部は次のとおりです。

procedure CurPageChanged(CurPageID: Integer);
begin
  If CurPageID=PageInstallationPersonnalisee.ID then
    begin
      ProgressBarLabelPageInstPerso.Caption := 'Initialisation...';
      if InstallTool1 = True then
        begin
          ProgressBarLabelPageInstPerso.Caption := 'Installing InstallTool1...';
          F_InstallTool1();
        end;
      if InstallTool2 = True then
        begin
          ProgressBarLabelPageInstPerso.Caption := 'Installing InstallTool2...';
          F_InstallTool2();
        end;
      if InstallTool3 = True then
        begin
          ProgressBarLabelPageInstPerso.Caption := 'Installing InstallTool3...';
          F_InstallTool3();
        end;

      ProgressBarPageInstPerso.Style := npbstMarquee;
      //ProgressBarPageInstPerso.Style := npbstNormal;
      ProgressBarPageInstPerso.Position := 100;

      CancelWithoutPrompt:=True;
      WizardForm.Close;
    end;
end;

ExtractTemporaryFile()各F_InstallTooln()関数で作成されていることに注意してください。

役立つ可能性のあるセットアップセクションとファイルセクションの他の部分：

[Setup]
SolidCompression=no

[Files]
;Temporary redists
Source: "{#MyRessourcesPath}InstallTool1_Setup.exe"; DestDir: "{tmp}"; Flags: deleteafterinstall noencryption dontcopy
Source: "{#MyRessourcesPath}InstallTool2_Setup.exe"; DestDir: "{tmp}"; Flags: deleteafterinstall noencryption dontcopy
Source: "{#MyRessourcesPath}InstallTool3_Setup.exe"; DestDir: "{tmp}"; Flags: deleteafterinstall noencryption dontcopy

ここでは、PageInstallationPersonnaliseeのページは、最初のExtractTemporaryFileが完了するまで表示されません。

ExtractTemporaryFileによってインストールプロセスが遅れる可能性があることは承知していますが、なぜウィザードがフリーズする必要があるのでしょうか。

だから私の質問は：私のシナリオでは、ExtractTemporaryFileプロシージャが起動される前にウィザードが表示されるようにウィザードを強制的に更新する方法はありますか？

ExtractTemporaryFile本当にウィザード形式をハングアップします。ほとんどのコードがそうであるように。

Windowsメッセージキューを強制的に送り出すことができる唯一のカスタムページはTOutputProgressWizardPage（によって作成されたCreateOutputProgressPage）です。

あなたはこのようなことをすることができます：

function NextButtonClick(CurPageID: Integer): Boolean;
var
  ProgressPage: TOutputProgressWizardPage;
begin
  if CurPageID = wpReady then
  begin
    ProgressPage := CreateOutputProgressPage('Preparing installations', '');
    ProgressPage.Show;
    try
      ProgressPage.Msg1Label.Caption := 'Installing 1 ...';
      ProgressPage.SetProgress(0, 100);
      ExtractTemporaryFile('1.exe');
      Exec(...);

      ProgressPage.Msg1Label.Caption := 'Installing 2 ...';
      ProgressPage.SetProgress(33, 100);
      ExtractTemporaryFile('2.exe');
      Exec(...);

      ProgressPage.Msg1Label.Caption := 'Installing 3 ...';
      ProgressPage.SetProgress(66, 100);
      ExtractTemporaryFile('3.exe');
      Exec(...);

      ProgressPage.SetProgress(100, 100);
      ProgressPage.Hide;
    finally
    end;
  end;
  Result := True;
end;

SetProgress頻繁に呼び出すことができない場合は、アニメーション付きの派手なプログレスバーがある最新バージョンのWindowsでも、あまりうまく機能しません。SetProgress呼び出しは、バックグラウンドでメッセージキューをポンプするものであることに注意してください。したがって、パラメータが変更されていない場合でも、それを呼び出すことは理にかなっています。しかし、ExtractTemporaryFileブロックとしてはできません。

または、デプロイメントを[Files]セクションに任せて、AfterInstallイベントからインストーラーを実行することもできます。

[Files]
;Temporary redists
Source: "{#MyRessourcesPath}InstallTool1_Setup.exe"; DestDir: "{tmp}"; \
  Flags: deleteafterinstall noencryption dontcopy; AfterInstall: Install1
Source: "{#MyRessourcesPath}InstallTool2_Setup.exe"; DestDir: "{tmp}"; \
  Flags: deleteafterinstall noencryption dontcopy; AfterInstall: Install2
Source: "{#MyRessourcesPath}InstallTool3_Setup.exe"; DestDir: "{tmp}"; \
  Flags: deleteafterinstall noencryption dontcopy; AfterInstall: Install3

これが古いスレッドであることは知っていExtractTemporaryFileますが、関数を使用して抽出したファイルの一部が他のファイルよりも大幅に遅いという同様の状況に直面していました。

調査の結果、InnoSetupのヘルプページでこれを見つけました。

確実な圧縮が有効になっている場合は、[ファイル]セクションの上部（またはその近く）に一時ファイルをリストしてください。ソリッド圧縮インストールで任意のファイルを抽出するには、セットアップは最初に以前のすべてのファイルを（メモリ内の一時バッファに）解凍する必要があります。[ファイル]セクションで指定されたファイルの上に他の多くのファイルがリストされている場合、これにより大幅な遅延が発生する可能性があります。

つまり、最適なパフォーマンスを得るには、その関数を使用して抽出するファイルを[Files]セクションの先頭に移動する必要があります。