ExcelVBAでSelectを使用しないようにする方法

552
BiGXERO 2012-05-23 19:57.

.SelectExcel VBAでの使用の嫌悪感についてはよく耳にしますが、使用を避ける方法がわかりません。Select関数の代わりに変数を使用できれば、コードはより再利用可能になることがわかりました。ただし、をActiveCell使用しない場合の参照方法(など)がわかりませんSelect

私が発見した範囲でこの記事とselectを使用していないの利点にこの例を、私は上の何も見つけることができませんどのように

15 answers

578
chris neilsen 2012-05-24 00:23.

選択を回避する方法のいくつかの例

Dim'd変数を使用する

Dim rng as Range

Set必要な範囲の変数。単一セル範囲を参照する方法はたくさんあります。

Set rng = Range("A1")
Set rng = Cells(1, 1)
Set rng = Range("NamedRange")

またはマルチセル範囲:

Set rng = Range("A1:B10")
Set rng = Range("A1", "B10")
Set rng = Range(Cells(1, 1), Cells(10, 2))
Set rng = Range("AnotherNamedRange")
Set rng = Range("A1").Resize(10, 2)

あなたは可能にショートカットを使用Evaluateする方法が、これはあまり効率的であると一般的に生産コードでは避けるべきです。

Set rng = [A1]
Set rng = [A1:B10]

上記のすべての例は、アクティブシート上のセルを参照しています。特にアクティブシートのみを操作する場合を除いて、Worksheet変数を暗くすることをお勧めします。

Dim ws As Worksheet
Set ws = Worksheets("Sheet1")
Set rng = ws.Cells(1, 1)
With ws
    Set rng = .Range(.Cells(1, 1), .Cells(2, 10))
End With

を使用たい場合はActiveSheet、明確にするために明示的にするのが最善です。ただし、一部のWorksheet方法ではアクティブシートが変更されるため、注意してください。

Set rng = ActiveSheet.Range("A1")

繰り返しますが、これはアクティブなワークブックを指します。特にActiveWorkbookorのみを使用する場合を除いてThisWorkbookWorkbook変数をDimすることをお勧めします。

Dim wb As Workbook
Set wb = Application.Workbooks("Book1")
Set rng = wb.Worksheets("Sheet1").Range("A1")

を使用たい場合はActiveWorkbook、明確にするために明示的にするのが最善です。ただし、多くのWorkBook方法でアクティブな本が変わるため、注意してください。

Set rng = ActiveWorkbook.Worksheets("Sheet1").Range("A1")

ThisWorkbookオブジェクトを使用して、実行中のコードを含む本を参照することもできます。

Set rng = ThisWorkbook.Worksheets("Sheet1").Range("A1")

一般的な(悪い)コードは、本を開いてデータを取得してからもう一度閉じることです。

これは悪いです:

Sub foo()
    Dim v as Variant
    Workbooks("Book1.xlsx").Sheets(1).Range("A1").Clear
    Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
    v = ActiveWorkbook.Sheets(1).Range("A1").Value
    Workbooks("SomeAlreadyOpenBook.xlsx").Activate
    ActiveWorkbook.Sheets("SomeSheet").Range("A1").Value = v
    Workbooks(2).Activate
    ActiveWorkbook.Close()
End Sub

そしてそれはより良いでしょう:

Sub foo()
    Dim v as Variant
    Dim wb1 as Workbook
    Dim  wb2 as Workbook
    Set wb1 = Workbooks("SomeAlreadyOpenBook.xlsx")
    Set wb2 = Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
    v = wb2.Sheets("SomeSheet").Range("A1").Value
    wb1.Sheets("SomeOtherSheet").Range("A1").Value = v
    wb2.Close()
End Sub

範囲を範囲変数としてSubsとFunctionsに渡します。

Sub ClearRange(r as Range)
    r.ClearContents
    '....
End Sub

Sub MyMacro()
    Dim rng as Range
    Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:B10")
    ClearRange rng
End Sub

あなたはまた、(のような方法に適用すべきであるFindとしCopy、変数に):

Dim rng1 As Range
Dim rng2 As Range
Set rng1 = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10")
Set rng2 = ThisWorkbook.Worksheets("SomeSheet").Range("B1:B10")
rng1.Copy rng2

セルの範囲をループしている場合は、最初に範囲の値をバリアント配列にコピーして、それをループする方が良い(高速)ことがよくあります。

Dim dat As Variant
Dim rng As Range
Dim i As Long

Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10000")
dat = rng.Value  ' dat is now array (1 to 10000, 1 to 1)
for i = LBound(dat, 1) to UBound(dat, 1)
    dat(i,1) = dat(i, 1) * 10 ' Or whatever operation you need to perform
next
rng.Value = dat ' put new values back on sheet

これは、可能なことのための小さなテイスターです。

217
Siddharth Rout 2012-05-24 00:33.

2つの主な理由は、なぜ.Select.ActivateSelectionActivecellActivesheetActiveworkbook、などは避けるべきです

  1. それはあなたのコードを遅くします。
  2. これは通常、ランタイムエラーの主な原因です。

どうすればそれを回避できますか?

1)関連するオブジェクトを直接操作する

このコードを検討してください

Sheets("Sheet1").Activate
Range("A1").Select
Selection.Value = "Blah"
Selection.NumberFormat = "@"

このコードは次のように書くこともできます

With Sheets("Sheet1").Range("A1")
    .Value = "Blah"
    .NumberFormat = "@"
End With

2)必要に応じて、変数を宣言します。上記と同じコードは次のように書くことができます

Dim ws as worksheet

Set ws = Sheets("Sheet1")

With ws.Range("A1")
    .Value = "Blah"
    .NumberFormat = "@"
End With
89
Rick supports Monica 2014-05-29 04:04.

私が以前に与えられたすべての優れた答えに追加する1つの小さな強調点:

おそらく、Selectの使用を回避するためにできる最大のことは、VBAコードで名前付き範囲(意味のある変数名と組み合わせて)をできるだけ使用することです。この点については前述しましたが、少し光沢がありました。ただし、特別な注意が必要です。

名前付き範囲を自由に使用する理由は他にもいくつかありますが、もっと考えられると思います。

名前付き範囲を使用すると、コードが読みやすく、理解しやすくなります。

例:

Dim Months As Range
Dim MonthlySales As Range

Set Months = Range("Months")
' E.g, "Months" might be a named range referring to A1:A12

Set MonthlySales = Range("MonthlySales")
' E.g, "Monthly Sales" might be a named range referring to B1:B12

Dim Month As Range
For Each Month in Months
    Debug.Print MonthlySales(Month.Row)
Next Month

それは何という名前の範囲はかなり明白であるMonthsMonthlySales含まれており、手順が何をしていますか。

何でこれが大切ですか?他の人が理解しやすいという理由もありますが、コードを見たり使用したりするのがあなただけであっても、意図したことを忘れてしまうため、名前付き範囲と適切な変数名を使用する必要があります。1年後、コードが何をしているのかを理解するだけで30分を無駄にします。

名前付き範囲は、スプレッドシートの構成が変更されたときに(そうでない場合でも)マクロが壊れないようにします。

上記の例が次のように記述されている場合を考えてみます。

Dim rng1 As Range
Dim rng2 As Range

Set rng1 = Range("A1:A12")
Set rng2 = Range("B1:B12")

Dim rng3 As Range
For Each rng3 in rng1
    Debug.Print rng2(rng3.Row)
Next rng3

このコードは最初は問題なく機能します。つまり、あなたまたは将来のユーザーが「gee wiz、列に年を含む新しい列を追加するつもりですA!」と決定するか、月と月の間に経費列を配置するまでです。販売列、または各列にヘッダーを追加します。今、あなたのコードは壊れています。また、ひどい変数名を使用したため、修正方法を理解するのに必要以上に時間がかかります。

最初に名前付き範囲を使用していた場合はMonthsSales列と列を好きなように移動でき、コードは引き続き正常に機能します。

48
MattB 2014-02-28 11:09.

他のみんなが長い答えをしたので、私は短い答えをするつもりです。

マクロを記録して再利用するたびに、.selectと.activateを取得します。セルまたはシートを選択すると、アクティブになります。その時点からRange.Value、アクティブなセルとシートを使用するような非修飾参照を使用するときはいつでも。これは、コードが配置されている場所を監視していない場合や、ユーザーがブックをクリックした場合にも問題になる可能性があります。

したがって、セルを直接参照することで、これらの問題を解消できます。どちらが行く:

'create and set a range
Dim Rng As Excel.Range
Set Rng = Workbooks("Book1").Worksheets("Sheet1").Range("A1")
'OR
Set Rng = Workbooks(1).Worksheets(1).Cells(1, 1)

またはあなたはできます

'Just deal with the cell directly rather than creating a range
'I want to put the string "Hello" in Range A1 of sheet 1
Workbooks("Book1").Worksheets("Sheet1").Range("A1").value = "Hello"
'OR
Workbooks(1).Worksheets(1).Cells(1, 1).value = "Hello"

これらの方法にはさまざまな組み合わせがありますが、それは私のようなせっかちな人々のためにできるだけ短く表現される一般的な考えです。

34
Noname 2015-02-25 05:41.

「...そして、Select関数の代わりに変数を使用できれば、コードがより再利用可能になることがわかりました。」

.Select直接セル参照よりも良い選択となる、孤立した一握りの状況しかSelection考えられませんが、.Select回避すべき同じ理由でそれを捨てるべきではないことを擁護し、指摘します。

いくつかのキーをタップするだけで利用できるホットキーの組み合わせに割り当てられた短い時間節約のマクロサブルーチンを使用すると、多くの時間を節約できる場合があります。ワークシート全体のデータ形式に準拠していないポケットデータを処理する場合、セルのグループを選択して操作コードを実行できるのは不思議です。セルのグループを選択して形式の変更を適用するのと同じように、特別なマクロコードを実行するセルのグループを選択すると、時間を大幅に節約できます。

選択ベースのサブフレームワークの例:

Public Sub Run_on_Selected()
    Dim rng As Range, rSEL As Range
    Set rSEL = Selection    'store the current selection in case it changes
    For Each rng In rSEL
        Debug.Print rng.Address(0, 0)
        'cell-by-cell operational code here
    Next rng
    Set rSEL = Nothing
End Sub

Public Sub Run_on_Selected_Visible()
    'this is better for selected ranges on filtered data or containing hidden rows/columns
    Dim rng As Range, rSEL As Range
    Set rSEL = Selection    'store the current selection in case it changes
    For Each rng In rSEL.SpecialCells(xlCellTypeVisible)
        Debug.Print rng.Address(0, 0)
        'cell-by-cell operational code here
    Next rng
    Set rSEL = Nothing
End Sub

Public Sub Run_on_Discontiguous_Area()
    'this is better for selected ranges of discontiguous areas
    Dim ara As Range, rng As Range, rSEL As Range
    Set rSEL = Selection    'store the current selection in case it changes
    For Each ara In rSEL.Areas
        Debug.Print ara.Address(0, 0)
        'cell group operational code here
        For Each rng In ara.Areas
            Debug.Print rng.Address(0, 0)
            'cell-by-cell operational code here
        Next rng
    Next ara
    Set rSEL = Nothing
End Sub

処理する実際のコードは、1行から複数​​のモジュールまで何でもかまいません。私はこの方法を使用して、外部ワークブックのファイル名を含むセルの不規則な選択に対して長時間実行されるルーチンを開始しました。

つまり、Selection.Selectと密接に関連しているため、破棄しないでくださいActiveCell。ワークシートのプロパティとして、他にも多くの目的があります。

(はい、私はこの質問がについて.Selectであったことを知っていますがSelection、初心者のVBAコーダーが推測するかもしれない誤解を取り除きたいと思いました。)

30
Vityata 2016-03-09 00:04.

回避SelectActivateVBAの開発者、あなたが少し良くなり動きです。一般に、SelectおよびActivateはマクロが記録されるときに使用されるため、Parentワークシートまたは範囲は常にアクティブなものと見なされます。

これは回避することができる方法ですSelectActivate、以下の場合には:


新しいワークシートを追加し、その上にセルをコピーします。

From(マクロレコーダーで生成されたコード):

Sub Makro2()
    Range("B2").Select
    Sheets.Add After:=ActiveSheet
    Sheets("Tabelle1").Select
    Sheets("Tabelle1").Name = "NewName"
    ActiveCell.FormulaR1C1 = "12"
    Range("B2").Select
    Selection.Copy
    Range("B3").Select
    ActiveSheet.Paste
    Application.CutCopyMode = False
End Sub

に:

Sub TestMe()
    Dim ws As Worksheet
    Set ws = Worksheets.Add
    With ws
        .Name = "NewName"
        .Range("B2") = 12
        .Range("B2").Copy Destination:=.Range("B3")
    End With
End Sub

ワークシート間の範囲をコピーする場合:

から:

Sheets("Source").Select
Columns("A:D").Select
Selection.Copy
Sheets("Target").Select
Columns("A:D").Select
ActiveSheet.Paste

に:

Worksheets("Source").Columns("A:D").Copy Destination:=Worksheets("Target").Range("a1")

派手な名前付き範囲の使用

[]他の方法と比較して、本当に美しい、でそれらにアクセスできます。自分自身で調べて:

Dim Months As Range
Dim MonthlySales As Range

Set Months = Range("Months")    
Set MonthlySales = Range("MonthlySales")

Set Months =[Months]
Set MonthlySales = [MonthlySales]

上記の例は次のようになります。

Worksheets("Source").Columns("A:D").Copy Destination:=Worksheets("Target").[A1]

値をコピーするのではなく、取得する

通常、あなたが喜んでであるならばselect、おそらくあなたは何かをコピーしています。値のみに関心がある場合、これは選択を避けるための良いオプションです。

Range("B1:B6").Value = Range("A1:A6").Value


常にワークシートも参照するようにしてください

これはおそらくvbaで最も一般的な間違いです。範囲をコピーするたびに、ワークシートが参照されないことがあるため、VBAは間違ったシートをActiveWorksheetと見なします。

'This will work only if the 2. Worksheet is selected!
Public Sub TestMe()
    Dim rng As Range
    Set rng = Worksheets(2).Range(Cells(1, 1), Cells(2, 2)).Copy
End Sub

'This works always!
Public Sub TestMe2()
    Dim rng As Range
    With Worksheets(2)
        .Range(.Cells(1, 1), .Cells(2, 2)).Copy
    End With
End Sub

私は本当に.Selectまたは.Activate何かのために使用することはできませんか?

  • あなたが使用して正当化することができたときの良い例.Activate.Selectは、特定のワークシートを視覚的理由のために選択されていることを確認したいときです。たとえば、ファイルが閉じられたときにどちらがActiveSheetであったかを無視して、Excelは常に最初に選択されたカバーワークシートで開きます。

したがって、以下のコードのようなものは絶対にOKです:

Private Sub Workbook_Open()
    Worksheets("Cover").Activate
End Sub
  • 別の良い例は、この場合に述べたように、すべてのシートを1つのPDFファイルにエクスポートする必要がある場合です-この例のVBAでselect / activeステートメントを回避するにはどうすればよいですか?

  • コマンドActiveWindowがActiveWindow.ZoomやActiveWindow.FreezePanesのようにのみ機能する場合

30
Francesco Baruchelli 2012-05-23 20:11.

以下では、選択アプローチ(OPが避けたいアプローチ)と範囲アプローチ(これが質問への回答)を比較していることに注意してください。したがって、最初のSelectが表示されたら、読むのをやめないでください。

それは本当にあなたがやろうとしていることに依存します。とにかく、簡単な例が役立つかもしれません。アクティブセルの値を「foo」に設定するとします。ActiveCellを使用すると、次のようになります。

Sub Macro1()
    ActiveCell.Value = "foo"
End Sub

たとえば「B2」のように、アクティブではないセルに使用する場合は、次のように最初に選択する必要があります。

Sub Macro2()
    Range("B2").Select
    Macro1
End Sub

Rangesを使用すると、任意のセルの値を任意の値に設定するために使用できる、より一般的なマクロを作成できます。

Sub SetValue(cellAddress As String, aVal As Variant)
    Range(cellAddress).Value = aVal
End Sub

次に、Macro2を次のように書き直すことができます。

Sub Macro2()
    SetCellValue "B2", "foo"
End Sub

そしてMacro1は:

Sub Macro1()
    SetValue ActiveCell.Address, "foo"
End Sub
18
user1644564 2014-08-25 23:54.

常にワークブック、ワークシート、セル/範囲を記載してください。

例えば:

Thisworkbook.Worksheets("fred").cells(1,1)
Workbooks("bob").Worksheets("fred").cells(1,1)

エンドユーザーは常にボタンをクリックするだけであり、フォーカスがワークブックから離れるとすぐにコードが処理したいので、事態は完全にうまくいきません。

また、ブックのインデックスは絶対に使用しないでください。

Workbooks(1).Worksheets("fred").cells(1,1)

ユーザーがコードを実行したときに他にどのようなブックが開かれるかはわかりません。

11
LFB 2018-06-17 04:18.

これらの方法はかなり汚名を着せられているので、砂に線を引くためにVityataとJeepedの主導権を握ります。

コール.Activate.SelectSelectionActiveSomethingメソッド/プロパティ

基本的には、主にアプリケーションUIを介したユーザー入力を処理するために呼び出されるためです。これらは、ユーザーがUIを介してオブジェクトを処理するときに呼び出されるメソッドであるため、マクロレコーダーによって記録されるメソッドです。そのため、ほとんどの状況で、それらを呼び出すことは脆弱または冗長です。選択する必要はありません。Selection直後にアクションを実行するようにオブジェクト。

ただし、この定義は、それらが要求される状況を解決します。

ときに呼び出す.Activate.Select.Selection.ActiveSomethingメソッド/プロパティ

基本的に、最終ユーザーが実行で役割を果たすことを期待する場合。

開発中であり、ユーザーがコードで処理するオブジェクトインスタンスを選択することを期待している場合は、.Selectionまたは.ActiveObjectが適切です。

一方、.Selectそして.Activateあなたは、ユーザーの次のアクションを推測することができますし、あなたのコードがユーザーをガイドしたい、おそらく彼/彼女のいくつかの時間とマウスクリックを保存する際に有用です。たとえば、コードがグラフの新しいインスタンスを作成したり、更新したりした場合、ユーザーはそれをチェックアウトしたいと思うかもしれません。そのため、グラフ.Activateまたはそのシートを呼び出して、ユーザーがグラフを検索する時間を節約できます。または、ユーザーがいくつかの範囲値を更新する必要があることがわかっている場合は、プログラムでその範囲を選択できます。

6
Eleshar 2016-11-21 05:02.

IMHOの使用は.select、私のようにマクロを記録してコードを変更することで必然的にVBAを学び始め.select、その後selectionは不要な仲介者であることに気付かずにコードを変更する人々から来ています。

.select すでに投稿されているように、既存のオブジェクトを直接操作することで回避できます。これにより、複雑な方法でiとjを計算し、cell(i、j)を編集するなど、さまざまな間接参照が可能になります。

それ以外の場合は、.selectそれ自体に暗黙の問題はなく、これの使用法を簡単に見つけることができます。たとえば、日付を入力したスプレッドシートがあり、それを使って魔法をかけるマクロをアクティブにし、別のシートに受け入れ可能な形式でエクスポートします。ただし、隣接するセルへの最終的な手動(予測不可能な)入力が必要です。そのため.select、マウスをさらに動かしてクリックする手間を省くことができます。

4
FinPro.Online 2016-09-08 20:36.

この.Selectメソッドの使用を回避するために、必要なプロパティに等しい変数を設定できます。

►たとえば、値がCell A1必要な場合は、そのセルのvalueプロパティに等しい変数を設定できます。

  • valOne = Range("A1").Value

►たとえばyou could set a variable equal to the、そのワークシートの「Sheet3Codename」プロパティのコードネームが必要な場合。

  • valTwo = Sheets("Sheet3").Codename
3
PGSystemTester 2018-08-17 10:07.

これらの回答のいずれも.Offsetプロパティについて言及していないことに気づきました。これはSelect、特に選択したセルを参照して、特定のセルを操作するときにアクションを使用しないようにするためにも使用できます(OPがで言及しているようにActiveCell)。

ここにいくつかの例があります。

また、「ActiveCell」はJ4であると想定します。

ActiveCell.Offset(2, 0).Value = 12

  • これにより、セルJ6が12の値に変更されます
  • マイナス-2はJ2を参照しているでしょう

ActiveCell.Offset(0,1).Copy ActiveCell.Offset(,2)

  • これにより、セルがにコピーさk4L4ます。
  • 必要がない場合は、オフセットパラメータに「0」は必要ないことに注意してください(、2)
  • 前の例と同様に、マイナス1は i4

ActiveCell.Offset(, -1).EntireColumn.ClearContents

  • これにより、列kのすべてのセルの値がクリアされます。

これらは、上記のオプションよりも「優れている」と言っているのではなく、代替案をリストしているだけです。

1
Dominique 2020-10-31 05:55.

コピー&ペーストを回避する方法は?

それに直面しましょう:これはマクロを記録するときにたくさん現れます:

Range("X1").Select
Selection.Copy
Range("Y9).Select
Selection.Paste

人が望んでいるのは:

Range("Y9").Value = Range("X1").Value

したがって、VBAマクロでコピーと貼り付けを使用する代わりに、次の簡単なアプローチをお勧めします。

Destination_Range.Value = Source_Range.Value
0
barneyos 2019-10-30 23:45.

この例では、.Parent機能を使用して、myRng参照を1つだけ設定すると、.Select、.Activate、.Activecell、.ActiveWorkbook、.ActiveSheetなどを使用せずに環境全体に動的にアクセスできるようになります。(一般的な.Child機能はありません。)

Sub ShowParents()
    Dim myRng As Range
    Set myRng = ActiveCell
    Debug.Print myRng.Address                    ' An address of the selected cell
    Debug.Print myRng.Parent.name                ' The name of sheet, where MyRng is in
    Debug.Print myRng.Parent.Parent.name         ' The name of workbook, where MyRng is in
    Debug.Print myRng.Parent.Parent.Parent.name  ' The name of application, where MyRng is in

    ' You may use this feature to set reference to these objects
    Dim mySh  As Worksheet
    Dim myWbk As Workbook
    Dim myApp As Application

    Set mySh = myRng.Parent
    Set myWbk = myRng.Parent.Parent
    Set myApp = myRng.Parent.Parent.Parent
    Debug.Print mySh.name, mySh.Cells(10, 1).Value
    Debug.Print myWbk.name, myWbk.Sheets.Count
    Debug.Print myApp.name, myApp.Workbooks.Count

    ' You may use dynamically addressing
    With myRng
        .Copy

        ' Pastes in D1 on sheet 2 in the same workbook, where the copied cell is
        .Parent.Parent.Sheets(2).Range("D1").PasteSpecial xlValues

        ' Or myWbk.Sheets(2).Range("D1").PasteSpecial xlValues

        ' We may dynamically call active application too
        .Parent.Parent.Parent.CutCopyMode = False

        ' Or myApp.CutCopyMode = False
    End With
End Sub
0
Geoff Griswald 2020-03-03 03:04.

SelectまたはActivesheetを使用しない主な理由は、ほとんどの人がマクロの実行時に少なくとも別の2、3のワークブック(場合によっては数十)を開いており、マクロの実行中にシートから離れてクリックし、他のブックをクリックすると、開いているブックを開くと、「アクティブシート」が変更され、修飾されていない「選択」コマンドのターゲットワークブックも変更されます。

せいぜい、マクロはクラッシュします。最悪の場合、値を書き込んだり、間違ったブックにセルを変更したりして、それらを「元に戻す」方法がない可能性があります。

私が従う単純な黄金律があります。WorkbookオブジェクトとWorksheetオブジェクトに「wb」と「ws」という名前の変数を追加し、常にそれらを使用してマクロブックを参照します。複数の本、または複数のシートを参照する必要がある場合は、変数を追加します。

例えば、

Dim wb as Workbook
Dim ws as Worksheet
Set wb = ThisWorkBook
Set ws = wb.sheets("Output")

「Setwb = ThisWorkbook」コマンドは絶対に重要です。「ThisWorkbook」はExcelの特別な値であり、VBAコードが現在実行されているワークブックを意味します。Workbook変数を設定するための非常に便利なショートカット。

サブの上部でそれを行った後、それらを使用することは簡単ではありません。「選択」を使用する場所で使用してください。

したがって、「出力」のセル「A1」の値を次の代わりに「こんにちは」に変更するには、次のようにします。

Sheets("Output").Activate
ActiveSheet.Range("A1").Select
Selection.Value = "Hello"

これを行うことができます:

ws.Range("A1").Value = "Hello"

これは、ユーザーが複数のスプレッドシートで作業している場合に、はるかに信頼性が高く、クラッシュする可能性が低いだけではありません。また、はるかに短く、速く、簡単に書くことができます。

追加のボーナスとして、変数に常に「wb」と「ws」という名前を付けると、ある本から別の本にコードをコピーして貼り付けることができ、通常、必要な変更があれば最小限で機能します。

Related questions

MORE COOL STUFF

「水曜日」シーズン1の中心には大きなミステリーがあります

「水曜日」シーズン1の中心には大きなミステリーがあります

Netflixの「水曜日」は、典型的な10代のドラマ以上のものであり、実際、シーズン1にはその中心に大きなミステリーがあります.

ボディーランゲージの専門家は、州訪問中にカミラ・パーカー・ボウルズが輝くことを可能にした微妙なケイト・ミドルトンの動きを指摘しています

ボディーランゲージの専門家は、州訪問中にカミラ・パーカー・ボウルズが輝くことを可能にした微妙なケイト・ミドルトンの動きを指摘しています

ケイト・ミドルトンは、州の夕食会と州の訪問中にカミラ・パーカー・ボウルズからスポットライトを奪いたくなかった、と専門家は言う.

一部のファンがハリー・スタイルズとオリビア・ワイルドの「非常に友好的な」休憩が永続的であることを望んでいる理由

一部のファンがハリー・スタイルズとオリビア・ワイルドの「非常に友好的な」休憩が永続的であることを望んでいる理由

一部のファンが、オリビア・ワイルドが彼女とハリー・スタイルズとの間の「難しい」が「非常に友好的」な分割を恒久的にすることを望んでいる理由を見つけてください.

エリザベス女王の死後、ケイト・ミドルトンはまだ「非常に困難な時期」を過ごしている、と王室の専門家が明らかにする 

エリザベス女王の死後、ケイト・ミドルトンはまだ「非常に困難な時期」を過ごしている、と王室の専門家が明らかにする 

エリザベス女王の死後、ケイト・ミドルトンが舞台裏で「非常に困難な時期」を過ごしていたと伝えられている理由を調べてください.

セントヘレナのジェイコブのはしごを登るのは、気弱な人向けではありません

セントヘレナのジェイコブのはしごを登るのは、気弱な人向けではありません

セント ヘレナ島のジェイコブズ ラダーは 699 段の真っ直ぐ上る階段で、頂上に到達すると証明書が発行されるほどの難易度です。

The Secrets of Airline Travel Quiz

The Secrets of Airline Travel Quiz

Air travel is far more than getting from point A to point B safely. How much do you know about the million little details that go into flying on airplanes?

Where in the World Are You? Take our GeoGuesser Quiz

Where in the World Are You? Take our GeoGuesser Quiz

The world is a huge place, yet some GeoGuessr players know locations in mere seconds. Are you one of GeoGuessr's gifted elite? Take our quiz to find out!

バイオニック読書はあなたをより速く読むことができますか?

バイオニック読書はあなたをより速く読むことができますか?

BionicReadingアプリの人気が爆発的に高まっています。しかし、それは本当にあなたを速読術にすることができますか?

パンデミックは終わったかもしれないが、Covid-19 は終わっていない

パンデミックは終わったかもしれないが、Covid-19 は終わっていない

2021 年 6 月 8 日にニューヨーク市で開催された covid-19 パンデミックで亡くなった人々の命を偲び、祝うために、ネーミング ザ ロスト メモリアルズが主催するイベントと行進の最中に、グリーンウッド墓地の正門から記念碑がぶら下がっています。週末、ジョー・バイデン大統領は、covid-19 パンデミックの終息を宣言しました。これは、過去 2 年以上にわたり、公の場でそうするための長い列の中で最新のものです。

デビル・イン・オハイオの予告編は、エミリー・デシャネルもオハイオにいることを明らかにしています

デビル・イン・オハイオの予告編は、エミリー・デシャネルもオハイオにいることを明らかにしています

オハイオ州のエミリー・デシャネル みんな早く来て、ボーンズが帰ってきた!まあ、ショーボーンズではなく、彼女を演じた俳優. エミリー・デシャネルに最後に会ってからしばらく経ちました.Emily Deschanel は、長期にわたるプロシージャルな Bones の Temperance “Bones” Brennan としてよく知られています。

ドナルド・トランプはFBIのマー・ア・ラーゴ襲撃映像をリリースする予定ですか?

ドナルド・トランプはFBIのマー・ア・ラーゴ襲撃映像をリリースする予定ですか?

どうやら、ドナルド・トランプに近い人々は、今月初めにFBIによって家宅捜索された彼のMar-a-Lago財産からの映像を公開するよう彼に勧めています. 前大統領はテープを公開するかどうかを確認していませんが、息子はフォックス・ニュースにそうなるだろうと語った.

Andor は、他の Star Wars ショーから大きな距離を置きます。

Andor は、他の Star Wars ショーから大きな距離を置きます。

アンドールの一場面。数十年前、ジョージ・ルーカスがスター・ウォーズのテレビ番組を制作するのを妨げた主な理由は、お金でした。

ケイト・ミドルトンとウィリアム王子は、彼らが子供たちと行っているスパイをテーマにした活動を共有しています

ケイト・ミドルトンとウィリアム王子は、彼らが子供たちと行っているスパイをテーマにした活動を共有しています

ケイト・ミドルトンとウィリアム王子は、子供向けのパズルの本の序文を書き、ジョージ王子、シャーロット王女、ルイ王子と一緒にテキストを読むと述べた.

事故で押しつぶされたスイカは、動物を喜ばせ水分補給するために野生生物保護団体に寄付されました

事故で押しつぶされたスイカは、動物を喜ばせ水分補給するために野生生物保護団体に寄付されました

Yak's Produce は、数十個のつぶれたメロンを野生動物のリハビリ専門家であるレスリー グリーンと彼女のルイジアナ州の救助施設で暮らす 42 匹の動物に寄付しました。

デミ・ロヴァートは、新しいミュージシャンのボーイフレンドと「幸せで健康的な関係」にあります: ソース

デミ・ロヴァートは、新しいミュージシャンのボーイフレンドと「幸せで健康的な関係」にあります: ソース

8 枚目のスタジオ アルバムのリリースに向けて準備を進めているデミ ロヴァートは、「スーパー グレート ガイ」と付き合っている、と情報筋は PEOPLE に確認しています。

Plathville の Kim と Olivia Plath が数年ぶりに言葉を交わすことへようこそ

Plathville の Kim と Olivia Plath が数年ぶりに言葉を交わすことへようこそ

イーサン プラスの誕生日のお祝いは、TLC のウェルカム トゥ プラスビルのシーズン 4 のフィナーレで、戦争中の母親のキム プラスと妻のオリビア プラスを結びつけました。

仕事の生産性を高める 8 つのシンプルなホーム オフィスのセットアップのアイデア

仕事の生産性を高める 8 つのシンプルなホーム オフィスのセットアップのアイデア

ホームオフィスのセットアップ術を極めよう!AppExert の開発者は、家族全員が一緒にいる場合でも、在宅勤務の技術を習得しています。祖父や曽祖父が共同家族で暮らしていた頃の記憶がよみがえりました。

2022 年、私たちのデジタル ライフはどこで終わり、「リアル ライフ」はどこから始まるのでしょうか?

20 年前のタイムトラベラーでさえ、日常生活におけるデジタルおよびインターネットベースのサービスの重要性に驚くことでしょう。MySpace、eBay、Napster などのプラットフォームは、高速化に焦点を合わせた世界がどのようなものになるかを示してくれました。

ニューロマーケティングの秘密科学

ニューロマーケティングの秘密科学

マーケティング担当者が人間の欲望を操作するために使用する、最先端の (気味が悪いと言う人もいます) メソッドを探ります。カートをいっぱいにして 3 桁の領収書を持って店を出る前に、ほんの数点の商品を買いに行ったことはありませんか? あなたは一人じゃない。

地理情報システムの日: GIS 開発者として学ぶべき最高の技術スタック

地理情報システムの日: GIS 開発者として学ぶべき最高の技術スタック

私たちが住んでいる世界を確実に理解するには、データが必要です。ただし、空間参照がない場合、このデータは地理的コンテキストがないと役に立たなくなる可能性があります。

Language