バッチファイルに引数を渡すにはどうすればよいですか?

1191
Keng 2008-08-26 08:14.

IDとパスワードをファイルにハードコーディングするのではなく、実行時にバッチファイルに渡す必要があります。

コマンドラインは次のようになります。

test.cmd admin [email protected] > test-log.txt

18 answers

1060
Greg Hewgill 2008-08-26 09:41.

もう1つの便利なヒントは、%*「すべて」を意味するために使用することです。例えば:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

実行する場合:

test-command admin password foo bar

上記のバッチファイルが実行されます。

fake-command /u admin /p password admin password foo bar

構文が少し間違っているかもしれませんが、これは一般的な考え方です。

294
Keng 2008-09-19 02:26.

これが私がそれをした方法です:

@fake-command /u %1 /p %2

コマンドは次のようになります。

test.cmd admin [email protected] > test-log.txt

%1最初のパラメータに適用されます%2(ここでトリッキーな部分です)第二に適用されます。この方法で最大9つのパラメーターを渡すことができます。

148
thelsdj 2008-08-26 10:03.

欠落しているパラメータをインテリジェントに処理したい場合は、次のようなことができます。

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1
91
jeb 2011-03-31 12:16.

バッチパラメータへのアクセスは、%1、%2、...%9、または%*を使用して簡単に行うことができますが
、コンテンツが単純な場合に限ります。

"&"^&エラーを発生させずに%1にアクセスすることはできないため、のような複雑なコンテンツを簡単に作成する方法はありません。

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

線はに拡大します

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

そして、の1つが&引用符の外にあるため、各行は失敗します。

これは、一時ファイルからパラメータの注釈付きバージョンを読み取ることで解決できます。

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

秘訣はecho onremステートメントの後に%1を有効にして展開することです(%2 .. %*)でも機能します。
その"&"&ため、前述のように、エラーを発生させることなくエコーすることもできます。

ただし、の出力をリダイレクトできるようにするにはecho on、2つのforループが必要です。

余分な文字* #は、のようなコンテンツに対して安全であるために使用されます/?(のヘルプが表示されますREM)。
または、行末のキャレット^は、rem。の後であっても、複数行の文字として機能する可能性があります。

次に、ファイルから出力されたremパラメーターを注意深く読み取ります。
FOR / Fは、遅延拡張をオフにして機能する必要があります。それ以外の場合は、「!」破壊されるでしょう。
の余分な文字を削除した後param1、あなたはそれを手に入れました。

またparam1、安全に使用するには、遅延拡張を有効にします。

61
Frank Krueger 2008-08-26 08:16.

うん、ちょうどのような変数を使用することを忘れないでください%%1使用している場合ifforギャングをしています。

doubleを忘れた場合は%、(おそらくnullの)コマンドライン引数に置き換えることになり、かなり紛らわしいエラーメッセージが表示されます。

53
DearWebby 2012-04-19 13:46.

複雑にする必要はありません。これは単にコマンド%1%2パラメータです。たとえば、

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

「一時停止」は、バッチファイルの実行内容を表示し、ANYキーが押されるのを待ちます。これをxx.batとしてWindowsフォルダーに保存します。

これを使用するには、次のように入力します。

xx c:\f\30\*.* f:\sites\30

このバッチファイルは、新しいファイルのみをコピーするなど、必要なすべてのパラメータを処理します。私はWindowsの前から使用しています。コピー中のファイルの名前を確認したい場合は、Qパラメーターを省略してください。

43
kodybrown 2017-07-13 17:32.

最近、友人からこの件について質問されたので、コマンドライン引数をバッチファイルで処理する方法を投稿したいと思いました。

この手法には、後で説明するように少しオーバーヘッドがありますが、バッチファイルを非常に理解しやすく、すばやく実装できます。次の構造をサポートするだけでなく:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

それのJISTを持っている:init:parse:main機能を。

使用例

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof
33
rightcodeatrighttime 2014-03-14 20:02.
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

注:IF"%1"==""%1引用符で囲まれていると、問題が発生します。

その場合はIF [%1]==[]IF "%~1"==""代わりに、NT 4(SP6)以降でのみまたはを使用してください。

24

これを単純にしましょう。

これが.cmdファイルです。

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

これがコマンドラインからの3つの呼び出しです。

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>
21
Amr Ali 2014-11-25 18:39.
FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

これは、引用符で囲まれているかどうかに関係なく、バッチパラメーター(%*)をループし、各パラメーターをエコーし​​ます。

21
The Godfather 2019-10-18 23:24.

バッチファイル内

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

%1そして%2、それぞれ最初と2番目の引数値を返します。

そして、コマンドラインで、引数を渡します

Directory> batchFileName admin [email protected] 

出力は

admin
[email protected]
20
Evan Kennedy 2016-02-17 14:24.

関数(または外部.bat)として呼び出すことができ、すべての変数を現在の環境に配置する簡単なread_paramsスクリプトを作成しました。関数はcall元のパラメーターのコピーで編集されているため、元のパラメーターは変更されません。

たとえば、次のコマンドを指定します。

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat 関数を呼び出した後、変数を使用できるようになります。

call :read_params %*

echo %random%
echo %greeting%

関数は次のとおりです。

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

制限事項

  • のような値のない引数をロードすることはできません-force。使用することはできます-force=trueが、値を持たないパラメーターのリストを事前に知らずに空白の値を許可する方法を考えることはできません。

変更ログ

  • 2016年2月18日
    • 拡張を遅らせる必要がなくなりました
    • -beforeパラメータを探すことにより、他のコマンドライン引数と連携するようになりました。
10
CMS_95 2013-11-15 08:16.

コマンドラインでセット変数を参照するには、次の%a%ように使用する必要があります。

set a=100 
echo %a%  
rem output = 100 

注:これはWindows 7proで機能します。

8
Garret Wilson 2018-06-02 16:41.

@Jonによる他の場所での回答に触発されて、名前付きパラメーター、オプションの値、およびスイッチを抽出するためのより一般的なアルゴリズムを作成しました。

ユーティリティを実装したいとしましょうfoobar。初期コマンドが必要です。これはオプションのパラメータ有する--fooかかるオプション(もちろん、他のパラメータとすることができません)の値を、値が欠落している場合、デフォルトでdefault。になります。また--bar必要な値をとるオプションのパラメーターもあります。最後に--baz、値が許可されていないフラグを取ることができます。ああ、そしてこれらのパラメータは任意の順序で来ることができます。

つまり、次のようになります。

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

解決策は次のとおりです。

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
  • SETLOCAL変数が呼び出し環境にエスケープしないように使用します。
  • SET FOO=呼び出し元の環境で誰かが変数を定義した場合に備えて、変数などを初期化することを忘れないでください。
  • %~1引用符を削除するために使用します。
  • 使用IF "%ARG%" == ""していないIF [%ARG%] == []ため[]スペースで終わる値を持つすべての意志を再生できません。
  • ブロックSHIFT内にいる場合でも、IFなどの現在の引数は%~1IFが解析されるときに決定されるため、更新されません。あなたは使用することができます%~1し、%~2内部のIFブロックが、あなたが持っていたので、それが混乱することでしょうSHIFTSHIFTわかりやすくするためにブロックの最後にを配置することもできますが、それは失われたり、人々を混乱させたりする可能性があります。したがって、「キャプチャ」%~1%~1てブロックの外側に配置するのが最適のようです。
  • 別のパラメータのオプション値の代わりにパラメータを使用したくないので、をチェックする必要がありIF NOT "%ARG:~0,2%" == "--"ます。
  • パラメータの1つSHIFT使用する場合にのみ注意してください。
  • 重複したコードSET FOO=%DEFAULT_FOO%は残念ですが、代わりIF "%FOO%" == "" SET FOO=%DEFAULT_FOO%IF NOT "%ARG%" == ""ブロックの外側に追加することもできます。これは内部でまだあるしかしのでIF "%PARAM%" == "--foo"ブロック、%FOO%値が評価されていたであろうと、あなたはブロックに入る前に、あなたがいることを検出することはないので、設定の両方の--fooパラメータが存在していたともという%FOO%値が欠落していました。
  • ECHO Missing bar value. 1>&2エラーメッセージをstderrに送信することに注意してください。
  • Want a blank line in a Windows batch file? You gotta use ECHO: or one of the variations.
4
SvenVP 2011-02-07 03:33.

Make a new batch file (example: openclass.bat) and write this line in the file:

java %~n1

Then place the batch file in, let's say, the system32 folder, go to your Java class file, right click, Properties, Open with..., then find your batch file, select it and that's that...

It works for me.

PS: I can't find a way to close the cmd window when I close the Java class. For now...

4
It Wasn't Me 2019-02-12 06:44.

For to use looping get all arguments and in pure batch:

Obs: For using without: ?*&<>


@echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && (
     call set "_arg_[!_cnt!]=!_arg_!" && for /l %%l in (!_cnt! 1 !_cnt!
     )do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

Your code is ready to do something with the argument number where it needs, like...

 @echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
 
 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
 
3
Amol Patil 2018-07-04 03:48.

Simple solution(even though question is old)

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

output

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

Where YourLocalPath is current directory path.

To keep things simple store the command param in variable and use variable for comparison.

Its not just simple to write but its simple to maintain as well so if later some other person or you read your script after long period of time, it will be easy to understand and maintain.

To write code inline : see other answers.

0
npocmaka 2020-11-10 00:20.

Paired arguments

If you prefer passing the arguments in a key-value pair you can use something like this:

@echo off

setlocal enableDelayedExpansion

:::::  asigning arguments as a key-value pairs:::::::::::::
set counter=0
for %%# in (%*) do (    
    set /a counter=counter+1
    set /a even=counter%%2
    
    if !even! == 0 (
        echo setting !prev! to %%#
        set "!prev!=%%~#"
    )
    set "prev=%%~#"
)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: showing the assignments
echo %one% %two% %three% %four% %five%

endlocal

And an example :

c:>argumentsDemo.bat one 1 "two" 2 three 3 four 4 "five" 5
1 2 3 4 5

Predefined variables

You can also set some environment variables in advance. It can be done by setting them in the console or setting them from my computer:

@echo off

if defined variable1 (
    echo %variable1%
)

if defined variable2 (
    echo %variable2%
)

and calling it like:

c:\>set variable1=1

c:\>set variable2=2

c:\>argumentsTest.bat
1
2

File with listed values

You can also point to a file where the needed values are preset. If this is the script:

@echo off

setlocal
::::::::::
set "VALUES_FILE=E:\scripts\values.txt"
:::::::::::


for /f "usebackq eol=: tokens=* delims=" %%# in ("%VALUES_FILE%") do set "%%#"

echo %key1% %key2% %some_other_key%

endlocal

and values file is this:

:::: use EOL=: in the FOR loop to use it as a comment

key1=value1

key2=value2

:::: do not left spaces arround the =
:::: or at the begining of the line

some_other_key=something else

and_one_more=more

the output of calling it will be:

value1 value2 something else

Of course you can combine all approaches. Check also arguments syntax , shift

Related questions

MORE COOL STUFF

ケイト・ブランシェットは3日間一緒に夫と一緒に寝て、25年経ってもまだ夫と結婚しています

ケイト・ブランシェットは3日間一緒に夫と一緒に寝て、25年経ってもまだ夫と結婚しています

ケイト・ブランシェットは、夫に会ったとき、典型的な交際のアドバイスに逆らいました。

マイケルシーンが非営利の俳優である理由

マイケルシーンが非営利の俳優である理由

マイケルシーンは非営利の俳優ですが、それは正確にはどういう意味ですか?

ホールマークスターのコリンエッグレスフィールドがRomaDramaLiveでスリル満点のファンと出会う![エクスクルーシブ]

ホールマークスターのコリンエッグレスフィールドがRomaDramaLiveでスリル満点のファンと出会う![エクスクルーシブ]

特徴的なスターのコリン・エッグレスフィールドは、RomaDrama Liveでのスリル満点のファンとの出会いについて料理しました!加えて、大会での彼のINSPIREプログラム。

「たどりつけば」をオンラインでストリーミングできない理由

「たどりつけば」をオンラインでストリーミングできない理由

ノーザンエクスポージャーが90年代の最も人気のある番組の1つになった理由を確認するには、Blu-rayまたはDVDプレーヤーをほこりで払う必要があります。

バイオニック読書はあなたをより速く読むことができますか?

バイオニック読書はあなたをより速く読むことができますか?

BionicReadingアプリの人気が爆発的に高まっています。しかし、それは本当にあなたを速読術にすることができますか?

ドミニカのボイリング湖:アクセスは簡単ではありませんが、ハイキングする価値があります

ドミニカのボイリング湖:アクセスは簡単ではありませんが、ハイキングする価値があります

ドミニカのボイリング湖は、世界で2番目に大きいボイリング湖です。そこにたどり着くまでのトレッキングは大変で長いですが、努力する価値は十分にあります。

私たちの水をきれいに保つのを助けるためにあなたの髪を寄付してください

私たちの水をきれいに保つのを助けるためにあなたの髪を寄付してください

サロンからのヘアトリミングや個人的な寄付は、油流出を吸収して環境を保護するのに役立つマットとして再利用できます。

ホワイトハウスの最も記憶に残る結婚式を見てください

ホワイトハウスの最も記憶に残る結婚式を見てください

過去200年以上の間にホワイトハウスで結婚したのはほんの数人です。彼らは誰でしたか、そしてそこで結婚式を獲得するために何が必要ですか?

この太陽に優しいショルダーバッグで一日中外出してください

この太陽に優しいショルダーバッグで一日中外出してください

画像クレジット:Richard Mackney / Flickrトラベリングライトは必需品だけを運ぶことを意味するかもしれませんが、デバイスを補充する方法がない外出先では、接続を維持するのが難しくなる可能性があります。それはあなたがすべての生き物の快適さやクールなガジェットを捨てる必要があるという意味ではありません、ただあなたがいくつかのより小さなものを手に入れる必要があるということです、そしておそらくあなた自身をジュースに保つためにいくつかの、例えば非正統的な充電装置を使うでしょう。

ミッドセンチュリーリゾートのポストカードが廃墟に変わるのを見る

ミッドセンチュリーリゾートのポストカードが廃墟に変わるのを見る

ニューヨーク州スプリンググレンにある放棄されたホモワックロッジのボーリング場。キャッツキル南部のこの地域は、ニューヨーク市からのユダヤ人の行楽客に人気があることから、かつてはボルシチベルトとして知られていました。

ブルックリンスレートの美しいボードをあなたのテーブルに座らせましょう

ブルックリンスレートの美しいボードをあなたのテーブルに座らせましょう

ブルックリンスレートブルックリンスレートのマグカップとコースターの賞賛をすでに歌っており、それらの食器製品も同様に堅実です。ブルックリンスレートは、さまざまなサイズとテクスチャのスレートの完全な採石場を販売しています。一部のオプションは赤でも利用できます。上で見ることができるように、彼らは同様にカスタマイズをします。

遺伝子分析により、私たちの体内に生息する微生物の99%がカタログ化されていないことが明らかになりました

遺伝子分析により、私たちの体内に生息する微生物の99%がカタログ化されていないことが明らかになりました

画像:Juan Gaertner / Shutterstock私たちの体の内部は、私たちの細胞とは何の関係もない何十億もの微生物が住んでいる本物の生態系です。これがまだ少し気になることではなかったかのように、これらの微生物の99%が研究されたことがないことがわかりました。

Zendaya Wishes Boyfriend Tom Holland Happy Birthday with Cuddly Photo: He 'Makes Me the Happiest'

Zendaya Wishes Boyfriend Tom Holland Happy Birthday with Cuddly Photo: He 'Makes Me the Happiest'

Zendaya shared a sweet photo in honor of boyfriend Tom Holland's 26th birthday Wednesday

小さな女性:脳卒中を患った後に病院から解放されたアトランタのジューシーな赤ちゃん:「まだ癒し」

小さな女性:脳卒中を患った後に病院から解放されたアトランタのジューシーな赤ちゃん:「まだ癒し」

シーレン「Ms.JuicyBaby」ピアソンは、先月脳卒中で入院した後、「もう一度たくさんのことをする方法を学ばなければならない」ため、言語療法を受けていることを明らかにしました。

エマストーンは彼女のクリフサイドマリブビーチハウスを420万ドルでリストアップしています—中を見てください!

エマストーンは彼女のクリフサイドマリブビーチハウスを420万ドルでリストアップしています—中を見てください!

オスカー受賞者の世紀半ばの家には、3つのベッドルーム、2つのバス、オーシャンフロントの景色があります。

ジーニー・メイ・ジェンキンスは、母乳育児の経験の中で、彼女は「本当に、本当に落ち込んでいる」と言います

ジーニー・メイ・ジェンキンスは、母乳育児の経験の中で、彼女は「本当に、本当に落ち込んでいる」と言います

ジーニー・メイ・ジェンキンスは、生後4か月の娘、モナコに母乳育児をしていると語った。

投資ノート:Bioscout AU$300万シード

投資ノート:Bioscout AU$300万シード

Bioscoutは、農家を運転席に置くという使命を負っています。Artesian(GrainInnovate)やUniseedと並んで、最新のシードラウンドでチームを支援できることをうれしく思います。問題真菌症による重大な作物の損失は、農民にとって試練であることが証明されています。

リトルマーケットリサーチ1| 2022年のクイックグリンプス遠隔医療市場

リトルマーケットリサーチ1| 2022年のクイックグリンプス遠隔医療市場

遠隔医療は、パンデミック後の時代では新しいものではなく、時代遅れの分野でもありません。しかし、業界を詳しく見ると、需要と供給の強力な持続可能性と、米国で絶え間ない革命となる強力な潜在的成長曲線を示しています。

スタートアップ資金調達環境:タイのスタートアップエコシステムの次は何ですか?

スタートアップ資金調達環境:タイのスタートアップエコシステムの次は何ですか?

2021年は、世界的なベンチャーキャピタル(VC)の資金調達にとって記録的な年でした。DealStreetAsiaによると、東南アジアも例外ではなく、この地域では年間で記録的な25の新しいユニコーンが採掘されました。

ムーアの法則を超えて

ムーアの法則を超えて

計算に対する私たちの欲求とムーアの法則が提供できるものとの間には、指数関数的に増大するギャップがあります。私たちの文明は計算に基づいています—建築と想像力の現在の限界を超える技術を見つけなければなりません。

Language